musicapp/app.moon

lapis = require "lapis"
console = require "lapis.console"

import respond_to from require "lapis.application"
import trim from require "lapis.util"
import process_tags from require "helpers"

import Tracks from require "models"

class extends lapis.Application
  "/console": console.make!

  [track: "/track/:id[%d]"]: respond_to {
    GET: =>
      if @track = Tracks\find id: tonumber @params.id
        @next = @track\next!
        @previous = @track\previous!
        return render: true
      else
        return redirect_to: @url_for "tracks"
    POST: =>
      if @track = Tracks\find id: tonumber @params.id
        updates = {}
        -- automatic tags
        for field in *{"artist", "mood", "link", "genre"}
          if @params[field]
            if @params.tags
              @params.tags ..= " #{field}:#{@params[field]}"
            else
              @params.tags = "#{field}:#{@params[field]}"
        -- update all fields
        for field in pairs Tracks.fields
          if @params[field]
            switch field
              when "status"
                updates.status = Tracks.statuses\for_db tonumber(@params.status) or @params.status
              when "quality"
                updates.quality = Tracks.qualities\for_db tonumber(@params.quality) or @params.quality
              when "tags"
                updates.tags = process_tags @params.tags
              when "id"
                nil -- IDs cannot be modified
              else
                updates[field] = trim @params[field]
        @track\update updates
        return redirect_to: @url_for "track", id: @track.id
      else
        return redirect_to: @url_for "tracks"
  }

  [tracks: "/tracks(/:order[%a])(/:asc_desc)(/:page[%d])"]: =>
    -- validate order field
    @order = tostring(@params.order)\lower!
    unless Tracks.fields[@order]
      @order = "id"
    -- validate ascending/descending (ascending default)
    @asc_desc = tostring(@params.asc_desc)\upper!
    if @asc_desc != "DESC" and @asc_desc != "ASC"
      @asc_desc = "ASC"
    @page = tonumber(@params.page) or 1

    tracks = Tracks\paginated "* ORDER BY #{@order} #{@asc_desc}", per_page: 32
    -- @last_page = tracks\num_pages! -- TODO figure out why this errors
    @last_page = 150
    -- validate page
    if @page < 1
      return redirect_to: @url_for "tracks", order: @order, asc_desc: @asc_desc, page: 1
    if @page > @last_page
      return redirect_to: @url_for "tracks", order: @order, asc_desc: @asc_desc, page: @last_page

    @tracks = tracks\get_page @page
    return render: true

  -- NOTE deprecated
  [index: "/(:page[%d])"]: respond_to {
    GET: =>
      tracks = Tracks\paginated "* ORDER BY id", per_page: 32
      @page = tonumber(@params.page) or 1
      @tracks = tracks\get_page @page
      render: true
    POST: =>
      if @params.id
        track = Tracks\find id: @params.id
        track\update {
          artist: @params.artist
          title: @params.title
          link: @params.link
          status: tonumber @params.status
        }
      else
        Tracks\create {
          artist: @params.artist
          title: @params.title
          link: @params.link
          status: @params.status
        }
      redirect_to: @url_for "index", page: @params.page
  }